*----------------- Data on Physical Fitness -----------------*
    | These measurements were made on men involved in a physical |
    | fitness course at N.C. State University.                   |
    | Only selected variables of                                 |
    | Oxygen (oxygen intake, ml per kg body weight per minute),  |
    | Runtime (time to run 1.5 miles in minutes), and            |
    | RunPulse (heart rate while running) are used.              |
    | Certain values were changed to missing for the analysis.   |
    *------------------------------------------------------------*;
    data FitMiss;
       input Oxygen RunTime RunPulse @@;
       datalines;
    44.609  11.37  178     45.313  10.07  185  
    54.297   8.65  156     59.571    .      .  
    49.874   9.22    .     44.811  11.63  176  
      .     11.95  176          .  10.85    .  
    39.442  13.08  174     60.055   8.63  170  
    50.541    .      .     37.388  14.03  186  
    44.754  11.12  176     47.273    .      .  
    51.855  10.33  166     49.156   8.95  180  
    40.836  10.95  168     46.672  10.00    .  
    46.774  10.25    .     50.388  10.08  168  
    39.407  12.63  174     46.080  11.17  156  
    45.441   9.63  164       .      8.92    .  
    45.118  11.08    .     39.203  12.88  168  
    45.790  10.47  186     50.545   9.93  148  
    48.673   9.40  186     47.920  11.50  170  
    47.467  10.50  170  
    ;
	run ;

/*  Suppose that the data are multivariate normally distributed 
	and that the missing data are missing at random (see the 
	"Statistical Assumptions for Multiple Imputation" section 
	in "The MI Procedure" chapter for a description of these 
	assumptions). The following statements use the MI procedure 
	to impute missing values for the FitMiss data set.
*/
	 proc mi data=FitMiss noprint out=outmi seed=3237851;   
      var Oxygen RunTime RunPulse; 
   run;

   /*
    The MI procedure creates imputed data sets, which are stored in the 
    outmi data set. A variable named _Imputation_ indicates the 
    imputation numbers. Based on m imputations, m different sets of the 
    point and variance estimates for a parameter can be computed. In this
    example, m=5 is the default. 
   The following statements generate regression coefficients for each of
   the five imputed data sets:
	*/

  proc reg data=outmi outest=outreg covout noprint;
      model Oxygen= RunTime RunPulse;
      by _Imputation_;
   run;

   proc print data=outreg(obs=8);
      var _Imputation_ _Type_ _Name_
         Intercept RunTime RunPulse;
      title 'Parameter Estimates from Imputed Data Sets';
   run;
/* The following statements combine the five sets of regression 
   coefficients: */
   proc mianalyze data=outreg;
      modeleffects Intercept RunTime RunPulse;
   run;